<?php
$h = '104';
$o = '111';
$l = '76';
$a = '97';
$ii = 0;
if(isset($_POST['button']))
{
$longitud = $string;
$lala = strlen($longitud); // longitud del string
echo "<br>";

while ($ii <= $lala) 
{
$letra = '';
$letra = substr ($string, $ii, 1); // devuelve un caracter
echo $letra;
echo "<br>";
$ii++;
}

}
?>

<form name="form1" method="post" action="">
  <p>String:
    <input type="text" name="string">
</p>
  <p>Ascii: 
    <input type="text" name="ascii" value="<?php echo $ascii; ?>" />
</p>
  <p>
    <input type="submit" name="button" value="Convertir">
  </p>
</form>

<?php
/* Coded By 5TU4RT */
$ii = 0;
if(isset($_POST['button']))
{
$longitud = $string;
$lala = strlen($longitud); // longitud del string

while ($ii < $lala) 
{
$letra = '';
$letra = substr ($string, $ii, 1); // devuelve un caracter
$ascii = ord($letra);
$total = $total.','.$ascii;
$ii++;
}
$final = substr ($total, 1);
}
?>

<form name="form1" method="post" action="">
  <p>String:
    <input type="text" name="string">
</p>
  <p>Ascii: 
    <input name="ascii" type="text" value="<?php echo $final; ?>">
</p>
  <p>
    <input type="submit" name="button" value="Convertir">
  </p>
</form>

Option Explicit

' En ADO, se usa el objeto Connection para abrir las bases de datos
Private cnn As ADODB.Connection
' Necesitamos los eventos si queremos controlar algunas cosillas
Private WithEvents rst As ADODB.Recordset

Private Sub Form_Load()
    '
    Text2 = ""
    '
    ' Indicar el path correcto de la base de datos
    ' ¡ACUERDATE DE PONER EL PATH CORRECTO!
    Const sPathBase As String = "C:\Program Files\Microsoft Visual Studio\VB98\BIBLIO.MDB"
    '
    ' Crear los objetos
    Set cnn = New ADODB.Connection
    Set rst = New ADODB.Recordset
    '
    ' Crear la conexión manualmente
    ' Usar "Provider=Microsoft.Jet.OLEDB.3.51;" para bases de Access 97
    ' Usar "Provider=Microsoft.Jet.OLEDB.4.0;"  para bases de Access 2000
    With cnn
        .ConnectionString = _
            "Provider=Microsoft.Jet.OLEDB.3.51;" & _
            "Data Source=" & sPathBase & ";"
        .Open
    End With
    ' Indicarle de que tabla vamos a leer los datos
    rst.Open "SELECT * FROM Authors", cnn, adOpenDynamic, adLockOptimistic
    '
    ' Asignar los nombres de los campos a las etiquetas
    Label1(0).Caption = "Au_ID:"
    Label1(1).Caption = "Author:"
    Label1(2).Caption = "Year Born:"
    '
    With ListView1
        ' El tipo de Listview que queremos es del tipo "reporte"
        .View = lvwReport
        ' Que muestre las líneas de separación entre datos
        .GridLines = True
        ' Que no se puedan modificar los datos del listview
        .LabelEdit = lvwManual
        ' Añadimos las cabeceras
        .ColumnHeaders.Add , , "Au_ID", 900
        .ColumnHeaders.Add , , "Autor", 2700
        .ColumnHeaders.Add , , "Año nacimiento", 1500, lvwColumnRight
    End With
    '
    ' Si hay datos, posicionarlo en el primer registro:
    cmdMover_Click 0
End Sub

Private Sub rst_MoveComplete(ByVal adReason As ADODB.EventReasonEnum, _
		ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, _
		ByVal pRecordset As ADODB.Recordset)
    ' Cada vez que el registro actual cambie,
    ' se producirá este evento (igual que con el DataControl)
    With rst
	'----------------------------------------------------------------------
	' Nota aclaratoria del 18/Dic/2003:
	' Cuando en un Recordset no hay datos, tanto BOF como EOF devuelven True
	'----------------------------------------------------------------------
        If .EOF And .BOF Then
            lblData.Caption = "No hay ningún registro activo"
            .MoveFirst
        Else
            Text1(0) = .Fields("Au_ID")
            ' Por si el dato es nulo, añadirle una cadena vacia
            Text1(1) = .Fields("Author") & ""
            Text1(2) = .Fields("Year Born") & ""
        End If
    End With
End Sub

Private Sub cmdMover_Click(Index As Integer)
    ' Mover según el botón pulsado
    'On Error Resume Next
    '
    With rst
        If Index = 0 Then       ' Primero
            .MoveFirst
        ElseIf Index = 1 Then   ' Anterior
            .MovePrevious
        ElseIf Index = 2 Then   ' Siguiente
            .MoveNext
        ElseIf Index = 3 Then   ' Último
            .MoveLast
        End If
        '
        If .BOF Or .EOF Then
            .MoveFirst
            lblData.Caption = " No hay datos..."
        Else
            lblData.Caption = " Registro actual: " & rst("Au_ID")
        End If
    End With
    '
    Err = 0
End Sub

Private Sub cmdAdd_Click()
    ' Añadir un nuevo registro
    rst.AddNew
    ' Añadimos algún texto, para que no se pierda este registro
    Text1(1) = "Nuevo"
    ' Actualizamos los datos
    rst.Update
    ' Movemos al último registro para que los cambios se hagan permanentes
    ' y se muestre el nuevo registro
    rst.MoveLast
End Sub

Private Sub cmdActualizar_Click()
    ' Guardar el contenido de las cajas de texto
    With rst
        ' Este campo es auto numérico, así que no asignarlo
        '.Fields("Au_ID") = Text1(0) + 0
        ' Añadimos una cadena vacía al final
        ' ya que si Text1(1) está vacío, se asignará un valor NULL y dará error
        .Fields("Author") = Text1(1) & ""
        ' Idem con el año de nacimiento, pero como es numérico, se sumará 0
        .Fields("Year Born") = Text1(2) + 0
        ' Actualizar los datos en el recordset
        .Update
    End With
End Sub

Private Sub cmdBorrar_Click()
    ' Borrar el registro actual
    ' Se comprueba que haya algún registro activo,
    ' para ello se comprueba que no hayamos pasado del principio o el final del Recordset
    '
    ' Comprobar que hay registros, porque si no hay, dará error
    If (rst.EOF Or rst.BOF) Then
        ' Avisar de que no hay registros
        lblData.Caption = "Ningún registro activo"
    Else
        ' Eliminar el registro actual
        rst.Delete
        '
        ' Movemos al primer registro para que los cambios se hagan permanentes
        ' (también podríamos haberlo movido al último registro)
        rst.MoveFirst
    End If
End Sub

Private Sub cmdBuscar_Click()
    ' Mostrar los datos en el listview
    Dim sBuscar As String
    Dim tRs As Recordset
    Dim tLi As ListItem
    '
    ' Comprobar si tiene caracteres "no válidos" para ADO:
    ' NOTA: Replace es una función de VB6
    sBuscar = Text2
    sBuscar = Replace(sBuscar, "*", "%")
    sBuscar = Replace(sBuscar, "?", "_")
    '
    Text2 = sBuscar
    ' Formar la cadena de la consulta:
    ' Se busca por el nombre del autor y se muestran clasificados por el nombre
    sBuscar = "SELECT * FROM Authors WHERE Author LIKE '" & sBuscar & "' ORDER BY Author"
    ' Creamos un recordset del tipo "estático", el cual no es modificable
    ' para poder modificarlo, tendría que ser del tipo dbOpenDynamic
    Set tRs = cnn.Execute(sBuscar)
    ' Comprobar que hay datos en el recordset
    With tRs
        ' Si no hay datos...
	'----------------------------------------------------------------------
	' Nota aclaratoria del 18/Dic/2003:
	' Cuando en un Recordset no hay datos, tanto BOF como EOF devuelven True
	'----------------------------------------------------------------------
        If (.BOF And .EOF) Then
            MsgBox "No se han encontrado los datos buscados"
        Else
            ' Mostrar los datos hallados
            ListView1.ListItems.Clear
            .MoveFirst
            Do While Not .EOF
                Set tLi = ListView1.ListItems.Add(, , .Fields("Au_ID") & "")
                tLi.SubItems(1) = .Fields("Author") & ""
                tLi.SubItems(2) = .Fields("Year Born") & ""
                .MoveNext
            Loop
        End If
    End With
End Sub

Private Function Replace(ByVal Expresion As String, _
                         ByVal Encontrar As String, _
                         ByVal ReemplazarCon As String) As String
    '---------------------------------------------------------------
    ' Función Replace para usar con VB5 o anteriores
    '---------------------------------------------------------------
    Dim i As Long, j As Long
    '
    j = 1
    Do
        ' Buscar la cadena indicada en la expresión
        i = InStr(j, Expresion, Encontrar)
        ' Si la hemos hallado, quitamos dicha cadena y ponemos la nueva
        If i Then
            Expresion = Left$(Expresion, i - 1) & ReemplazarCon & Mid$(Expresion, i + Len(Encontrar))
            j = i + 1
        End If
    Loop While i
    ' Devolver la cadena
    Replace = Expresion
End Function